Convert XML to JSON with Attributes and Text as Keys Without __text

The built-in feature doesn't allow for customization of the output. To achieve the expected output you need a custom transformation. It can be implemented by creating a recursive function that when it receives an object with attributes outputs an object with the current value under a new key with the same name than the existing key, and concatenating the attributes as new key-values. Otherwise return the value applying recursively the same transformation. Any other type is returning as is. My implementation includes mapping each element of an array though that there are no arrays in XML inputs. It should work with other format but I haven't tested it.

Example

Function:

%dw 2.0
output application/json 
fun writeWithAttributes(x) = x match {
    case o is Object -> 
        o mapObject ((value, key, index) ->
            if (isEmpty(key.@)) // if there are no attributes just return the same key and transform the value
                { (key): writeWithAttributes(value) } 
            else // if there are attributes add a new child object with the keys collected and the value repeating the same key.
                {
                    (key): { 
                        (key): writeWithAttributes(value), 
                        (key.@ mapObject ("@"++$$ as String): $) 
                    }
                } 
        )

    case a is Array -> a map writeWithAttributes($)
    else -> x
  }
---
writeWithAttributes(payload) 

Input:

<CustomData>
  <CustomIdentifier attribute1="value1" attribute2="value2">test</CustomIdentifier>
</CustomData>

Output:

{
  "CustomData": {
    "CustomIdentifier": {
      "CustomIdentifier": "test",
      "@attribute1": "value1",
      "@attribute2": "value2"
    }
  }
}