Multiple output based on input

Question

I'm trying to get different output depending on the input I have. But somehow I am not able to get that. I have different types of inputs & their respective outputs as below. How can I achive this using a single XSL.

input1

<response status="200">
    <Fields>
        <Field>
            <FieldName>ABC</FieldName>
        </Field>

        <Field>
            <FieldName>XYZ</FieldName>
        </Field>
    </Fields>
</response>

input2

<response status="200">
    <Fields>
        <Field>
            <FieldName>ABC</FieldName>
        </Field>
    </Fields>
</response>

The output1 gets genarated when I have the response like input1, and output2, when I have response like input2.

output1

<Body>
    <Response>
        <output>
            <Fields>
                <Field>
                    <FieldName>ABC</FieldName>
                </Field>

                <Field>
                    <FieldName>XYZ</FieldName>
                </Field>
            </Fields>
        </output>
    </Response>
</Body>

output2

<Body>
    <Response>
        <output>
            <Fields>
                <Field>
                    <FieldName>ABC</FieldName>
                </Field>
            </Fields>
        </output>
    </Response>
</Body>

So far I am able to manage to get output2 with the below simple xsl, but how to get both the output with a single xsl depending on the input? Any help will be really helpfull. Thanks.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>    

    <xsl:template match="/">
        <xsl:if test="/response/Fields/Field">
            <Body>
                <Response>
                    <output>
                        <Fields>
                            <Field>
                                <FieldName>
                                    <xsl:value-of select="/response/Fields/Field/FieldName"/>
                                </FieldName>
                            </Field>
                        </Fields>
                    </output>
                </Response>
            </Body>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Also how can I change the "FieldName" element name to fieldName after the transformation so that, my output looks like:

output1

<Body>
    <Response>
        <output>
            <Fields>
                <Field>
                    <fieldName>ABC</fieldName>
                </Field>

                <Field>
                    <fieldName>XYZ</fieldName>
                </Field>
            </Fields>
        </output>
    </Response>
</Body>

output2

<Body>
    <Response>
        <output>
            <Fields>
                <Field>
                    <fieldName>ABC</fieldName>
                </Field>
            </Fields>
        </output>
    </Response>
</Body>

michael.hor257k · Accepted Answer · 2016-07-27 11:17:46Z

2

How about simply:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/response">
    <Body>
        <Response>
            <output>
                <xsl:copy-of select="Fields"/>
            </output>
        </Response>
    </Body>
</xsl:template>

</xsl:stylesheet>

Added:

how can I rename the FieldName element to fieldName

Like this:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/response">
    <Body>
        <Response>
            <output>
                <xsl:apply-templates/>
            </output>
        </Response>
    </Body>
</xsl:template>

<xsl:template match="FieldName">
    <fieldName>
        <xsl:apply-templates/>
    </fieldName>
</xsl:template>

</xsl:stylesheet>

edited Jul 27, 2016 at 11:17

answered Jul 27, 2016 at 9:49

michael.hor257k

118k6 gold badges36 silver badges55 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Sammy Over a year ago

Hi Michael, how can I rename the FieldName element to fieldName after the transformation?

michael.hor257k Over a year ago

See the addition to my answer.

Himanshu · Accepted Answer · 2016-07-27 09:48:24Z

1

See this example: http://www.w3schools.com/xsl/

Print the top level tags once and the Field tags once for each FieldName tag

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>    

    <xsl:template match="/">
             <Body>
                <Response>
                    <output>
                        <Fields>
                        <xsl:for-each select="response/Fields/Field/FieldName">
                            <Field>
                                <FieldName>
                                    <xsl:value-of select="."/>
                                </FieldName>
                            </Field>
                        </xsl:for-each>
                        </Fields>
                    </output>
                </Response>
            </Body>
    </xsl:template>
</xsl:stylesheet>

answered Jul 27, 2016 at 9:48

Himanshu

2,4743 gold badges26 silver badges42 bronze badges

1 Comment

Sammy Over a year ago

Himanshu, how can I rename the FieldName element to fieldName after the transformation?

Collectives™ on Stack Overflow

Multiple output based on input

2 Answers 2

Added:

2 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Added:

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related