Test Setup in between data-driven style testing

Question

I have created some test cases using the data-driven style testing.

But when attaching the Test Setup/Teardown to the Setting section, both the setup and teardown runs before and after the testing all the data sets.

Robot

*** Settings ***
Test Setup  setup
Test Teardown  teardown

*** Keywords ***

Test Case Should Pass
    [Arguments]  ${arg1}  ${arg2}  ${arg3}
    something "${arg1}"
    something "${arg2}"
    something "${arg3}"

something "${arg}"
    Log To Console  ${arg}

setup
    Log To Console  setup

teardown
    Log To Console  teardown

*** Test Case ***

Test Case
    [Template]  Test Case Should Pass
    a1  a2  a3
    b1  b2  b3

Actual

==============================================================================
Something
==============================================================================
Test Case                                                             setup
.a1
a2
a3
.b1
b2
b3
.teardown
Test Case                                                             | PASS |
------------------------------------------------------------------------------
Something                                                             | PASS |
1 critical test, 1 passed, 0 failed
1 test total, 1 passed, 0 failed
==============================================================================

Expected

==============================================================================
Something
==============================================================================
Test Case                                                             setup
.a1
a2
a3
teardown
setup
.b1
b2
b3
.teardown
Test Case                                                             | PASS |
------------------------------------------------------------------------------
Something                                                             | PASS |
1 critical test, 1 passed, 0 failed
1 test total, 1 passed, 0 failed
==============================================================================

Are there any way that I can have the Setup/Teardown to be executed in between each data set tested?

asprtrmp · Accepted Answer · 2019-09-25 10:41:30Z

1

This would work:

*** Settings ***
Test Setup  setup
Test Teardown  teardown
Test Template  Test Case Should Pass

*** Keywords ***

Test Case Should Pass
    [Arguments]  ${arg1}  ${arg2}  ${arg3}
    something "${arg1}"
    something "${arg2}"
    something "${arg3}"

something "${arg}"
    Log To Console  ${arg}

setup
    Log To Console  setup

teardown
    Log To Console  teardown

*** Test Case ***
A
    a1  a2  a3
B
    b1  b2  b3

edited Sep 25, 2019 at 10:41

answered Sep 25, 2019 at 10:35

asprtrmp

1,0626 silver badges14 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Vix Over a year ago

I have tried this approach as well. But I was hoping that it can be achieved without having to put them under different test cases.

asprtrmp Over a year ago

Me too, however, it's not possible to use [Setup] in the template keyword, so it has to be introduced as a regular keyword as the first step of the template or do like this.

Collectives™ on Stack Overflow

Test Setup in between data-driven style testing

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related