Add 1 to number from cell in last row of sheet in other workbook and enter on sheet in currently open workbook

• Set wb1 = Workbooks("C:\Quotes\Quote List.xlsx") doesn't open the file.
• ws1.Range(lastrow).Value has syntax error. The column name is missing. eg. ws1.Range("A" & lastrow).Value

Try:

Sub Workbook_Open()
    Dim wb1 As Workbook 'Quote List
    Dim wb2 As Workbook 'My Quote
    Dim ws1 As Worksheet 'Quotes
    Dim ws2 As Worksheet 'Quote

    Set wb2 = ThisWorkbook
    Set ws2 = wb2.Sheets("Quote")
    On Error Resume Next
    Set wb1 = Workbooks("Quote List.xlsx")
    On Error GoTo 0
    If wb1 Is Nothing Then
        Set wb1 = Workbooks.Open("C:\Quotes\Quote List.xlsx")
    End If
    Set ws1 = wb1.Sheets("Quotes")
    ws2.Range("I1").Value = ws1.Cells(ws1.Rows.Count, "A").End(xlUp).Value + 1
End Sub

A Workbook Open: Retrieve Value from Closed Workbook

Option Explicit

Sub Workbook_Open()
    
    ' Define constants.
    Const SRC_FOLDER_PATH As String = "C:\Quotes\"
    Const SRC_FILE_NAME As String = "Quote List.xlsx"
    
    ' Attempt to reference the source workbook.
    Dim swb As Workbook:
    On Error Resume Next
        Set swb = Workbooks(SRC_FILE_NAME)
    On Error GoTo 0
    
    Dim sFilePath As String, WasSourceWorkbookOpen As Boolean
    
    ' If it's not open, open it.
    If swb Is Nothing Then ' source file is not open
        sFilePath = SRC_FOLDER_PATH & SRC_FILE_NAME
        Set swb = Workbooks.Open(sFilePath)
    Else ' source file is open
        WasSourceWorkbookOpen = True
    End If
    
    ' Reference the source worksheet.
    Dim sws As Worksheet: Set sws = swb.Sheets("Quotes")
    ' Reference the last source cell in column 'A'.
    Dim scell As Range:
    Set scell = sws.Cells(sws.Rows.Count, "A").End(xlUp)
    
    ' Reference the destination workbook, the workbook with the code.
    Dim dwb As Workbook: Set dwb = Me ' or 'Set dwb = ThisWorkbook'
    ' Reference the destination worksheet.
    Dim dws As Worksheet: Set dws = dwb.Sheets("Quote")
    ' Reference the destination cell.
    Dim dcell As Range: Set dcell = dws.Range("I1")
    
    ' Copy integer increased by 1 from source to destination.
    dcell.Value = scell.Value + 1
    
    ' Close the source workbook.
    If Not WasSourceWorkbookOpen Then ' was not open; close it
        swb.Close SaveChanges:=False
    'Else ' was open; do nothing???
    End If

    ' Inform.    
    MsgBox "Number retrieved.", vbInformation

End Sub