If - loop issues in Common Lisp

Since I mentioned count/counting in a comment, here's a version using it. loop itself handles initializing and incrementing the counter variables automatically, instead of you having to do it by hand, making it very convenient (And self-contained).

(defun count-in-list (y)
  (loop for elem in y
        count (< elem 32) into lower ; every time this test is true lower is incremented
        count (> elem 212) into upper ; and upper for this test
        finally (return (list lower upper)))) ; maybe return multiple values instead of a list?

Some annotations on your code.

(defun find-inlist (y)
  ;; upper and lower are not declared, if the Lisp environment is nice, at
  ;; best you are modifying global variables, which is not a good idea in
  ;; general. You can introduce new variables with (let ((upper 0) (lower 0))
  ;; ...) instead. Since you are using LOOP below, you can also start your
  ;; LOOP using: LOOP WITH UPPER = 0 AND LOWER = 0, which declares local
  ;; variables too.
  (setq upper 0)
  (setq lower 0)
  ;;
  (loop
    for element in y
    ;; (if ...) is an expression and produce a value, but what should be done of the value being
    ;; computed? Unless you instruct the LOOP macro to do something with it,
    ;; the value will be discarded. Here you have a syntax error because LOOP
    ;; expects a keyword, like DO, or COLLECT, etc.
       (if (< element 32)
           ;; (+ x y) computes "x + y", but does not update neither x nor y.
           ;; Maybe you wanted to assign the computed value to lower?
           ;;
           ;;     (setf lower (+ lower 1))
           ;;
           ;; If so, there is a shorthand notation, which is (incf lower)
           ;;
           (+ lower 1)
           ;; Same here
           (if (> elemen 212)
               (+ 1 upper)
               )))
  ;; If you use WITH in the LOOP declaration, then UPPER and LOWER won't be
  ;; visible here, but you can use FINALLY (RETURN (LIST ...)) in the LOOP.
  (list upper lower))

Also:

• You wrote elemen which is a typo
• (if x y) is better written as (when x y) (the same goes for unless when the then branch is nil.

(thanks @tripleee)

The corrected form of your code with somewhat minimal edits is:

(defun find-OUTlist      ;; NB!! Naming should NOT be misleading
       (y
          &aux               ;; auxiliary declarations marker
          (upper 0)          ;; local variables 
          (lower 0) )        ;; with their initial values
  (loop for element in y
        DO                   ;; keyword required 
        (if (< element 32) 
            (setf lower (+ lower 1))         ;; affect the value change
            (if (> element 212) 
                (setf upper (+ 1 upper)))))  ;; affect the value change
                         ;; CLHS: "Else-form-- The default is nil."
  (list lower upper))    ;; NB! More natural order

This code actually counts the elements which are OUTSIDE the range, and should not be named "...-inlist", which is misleading.

The return value is preferably given in the more natural, increasing order.