Commenting via REM and :: doesn't work in batch script

Question

I just want to leave a reminder about the %~ symbol combination, but my running my batch file outputs this:

C:\Users\batch\batch>add_one2The following usage of the path operator in batch-parameter
substitution is invalid: %~n' is passed argument
For valid formats type CALL /? or FOR /?
C:\Users\batch\batch>

Here's the script:

@echo off
REM '%~n' is passed argument
goto :main

:add_one
setlocal
    echo  Running 'add_one'...
endlocal & set /a %~1=%~2+1
goto :eof

:main
setlocal
    set /a x=1
    set /a y=50
    
    echo Created variable X and set it to %x%
    echo.
    call :add_one y %y%
    echo.
    echo The value of X is now %x%
endlocal
goto :eof

I tried ::, REM, and escaping in quotes, but it didn't work either.

Try to enclose the problematic part in quotes, not apostrphes: REM "%~n" is passed argument — Aacini
– Aacini, Commented Jun 19 at 19:15
Change it to a number. %~1. Apparently regardless of the line being a REM, the cmd parser still executes phase 1 which is percent expansion. %~n isn't a valid variable in a batch file. — Squashman
– Squashman, Commented Jun 19 at 19:52
Please read the DosTips forum topic: ECHO. FAILS to give text or blank line - Instead use ECHO/ There should be never used echo. to output a blank line as that results always in a file system access by cmd.exe searching in the current directory for a file with name echo. See Different echo?... variants with a very good and detailed information what is much better for the output of a blank line than echo. like echo/ or echo( and what are their pros and cons. — Mofi
– Mofi, Commented Jun 20 at 17:23

SomethingDark · Accepted Answer · 2025-06-19 19:49:52Z

Parameter expansion happens before other commands (see How does the Windows Command Interpreter (CMD.EXE) parse scripts? for much more detail), so the interpreter is trying to expand %~n before the REM command tells it that that line is a comment. Because argument-style variables must contain a digit, you will always get an error when you only use a letter.

For better information, use the actual variables in the function header documentation:

@echo off
goto :main

REM ===================================================
REM Arguments: %1 - The name of the variable to store
REM                 the value in
REM            %2 - The value to add
REM ===================================================
:add_one
setlocal
    echo  Running 'add_one'...
endlocal & set /a %~1=%~2+1
goto :eof

:main
setlocal
    set /a x=1
    set /a y=50
    
    echo Created variable X and set it to %x%
    echo.
    call :add_one y %y%
    echo.
    echo The value of X is now %x%
endlocal
goto :eof

Collectives™ on Stack Overflow

Commenting via REM and :: doesn't work in batch script

1 Answer 1

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related