Perl script to get the first element of arrays passed as reference

Question

I want to call a subroutine by passing around 4 arrays to it and then get the first value of each array and then create a new array(array of first elements of arrays that are passed) in the subroutine and then return back that array. Here is the code I tried with

my @a = (97,34,6,7);
my @b = ("A", "B", "F", "D");
my @c = (5..15);
my @d = (1..10);
my @tailings = popmany ( \@a, \@b, \@c, \@d );

print @tailings;

sub popmany {
    my @retlist = ();
    for my $aref (@_) {            #1
        my $arrele = @$aref;       #2
        push @retlist , $arrele    #3
    }
    return @retlist;
}

Here in #1 I use a loop and get the first array , then in line 2 I assign the whole array to a variable, thinking that by default the perl will only store the first variable of array into @arrele. the I push the $arrele to a new array @retlist , Sorry I dint refer any notes, so my procedure might be wrong. But this is throwing me a output like 441110

which has no sense.

Please explain me the code how can I do that.

popmany as a name is doubly misleading. pop removes the last element of an array and returns it. This returns the first value without altering the arrays. — TLP
– TLP, Commented Nov 11, 2011 at 11:57

Alex · Accepted Answer · 2011-11-11 07:48:07Z

16

It's here:

my $arrele = @$aref;

where you're asking perl to put @{$aref} into scalar context, which returns the length (number of elements in) the array pointed at by $aref.

Instead try:

my $arrele = $aref->[0];

which will access the first element of the array instead.

answered Nov 11, 2011 at 7:48

Alex

5,8932 gold badges31 silver badges46 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

mac Over a year ago

Thanks ... Can you tell me why my $arrele = $aref[0]; doesn't work ?

flesk Over a year ago

Because $aref is an array ref and you're trying to access it as an array. Try @$aref[0] instead if you desperately want to avoid $aref->[0] which is a lot clearer.

Alex Over a year ago

$aref[0] means "first element of array @aref" but $aref is a scalar containing a reference to some other array, so you need to use -> to dereference it first.

TLP Over a year ago

$$aref[0] is also a viable option.

flesk Over a year ago

I thought I wrote that in the comment above, but looking at it again, I see that I've accidentally used a one element array slice. :$

Eugene Yarmash · Accepted Answer · 2014-10-17 15:48:36Z

6

The line

my $arrele = @$aref;

assigns the length of the @$aref array to $arrele. To get the first element of the array you could use any of:

my $arrele = $$aref[0];
my $arrele = $aref->[0];    
my ($arrele) = @$aref;  # note the parenthesis which create list context

Also, since you generate a list based on another list, you could use map:

sub popmany {
    return map $_->[0], @_;
}

edited Oct 17, 2014 at 15:48

answered Nov 11, 2011 at 7:49

Eugene Yarmash

152k44 gold badges346 silver badges391 bronze badges

Comments

burning_LEGION · Accepted Answer · 2012-07-29 20:29:50Z

1

Far more simply written as

  sub popmany 
  {
    map $_->[0], @_;
  }

edited Jul 29, 2012 at 20:29

burning_LEGION

13.5k8 gold badges42 silver badges52 bronze badges

answered Nov 11, 2011 at 11:13

Borodin

127k9 gold badges72 silver badges146 bronze badges

1 Comment

user6839822 Over a year ago

Please leave simple code to codegolf questions. Easy code is the way to go, and this is not the easy way.

Eugene Yarmash · Accepted Answer · 2015-12-27 15:55:08Z

1

sub popmany { 
    my @retlist = (); 
    for my $aref (@_) { #1 
        my $arrele = @$aref[0]; #2 
        push @retlist , $arrele#3 
    } 
    return @retlist; 
}

edited Dec 27, 2015 at 15:55

Eugene Yarmash

152k44 gold badges346 silver badges391 bronze badges

answered Nov 11, 2011 at 7:53

run

1,1967 silver badges14 bronze badges

Collectives™ on Stack Overflow

Perl script to get the first element of arrays passed as reference

4 Answers 4

5 Comments

Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

5 Comments

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related